Доброго времени суток!

Уже очень долго бьюсь над одним запросом (ниже приведу его часть):

ВЫБРАТЬ
   Док_ЗаказПокупателя.Ответственный КАК МенеджерКС,
   ВзаиморасчетыСКонтрагентамиПоДокументамРасчетовОстатки.Контрагент КАК Контрагент,
   ВзаиморасчетыСКонтрагентамиПоДокументамРасчетовОстатки.ДоговорКонтрагента КАК ДоговорКонтрагента,
   РеализацияТоваровУслуг.СуммаДокумента,
   ЕСТЬNULL(РеализацияТоваровУслуг.ИсточникЗаказа, ЗНАЧЕНИЕ(Перечисление.ИсточникЗаказа.ПустаяСсылка)) КАК ИсточникЗаказа
ИЗ
   РегистрНакопления.ВзаиморасчетыСКонтрагентамиПоДокументамРасчетов.Остатки(
           &ДатаНач,
           ДокументРасчетовСКонтрагентом ССЫЛКА Документ.РеализацияТоваровУслуг) КАК ВзаиморасчетыСКонтрагентамиПоДокументамРасчетовОстатки
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
           ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.ЗаказПокупателя КАК Док_ЗаказПокупателя
           ПО РеализацияТоваровУслуг.Сделка.Ссылка = Док_ЗаказПокупателя.Ссылка
       ПО ВзаиморасчетыСКонтрагентамиПоДокументамРасчетовОстатки.ДокументРасчетовСКонтрагентом.Ссылка = РеализацияТоваровУслуг.Ссылка
ГДЕ
   ВзаиморасчетыСКонтрагентамиПоДокументамРасчетовОстатки.ДокументРасчетовСКонтрагентом ССЫЛКА Документ.РеализацияТоваровУслуг
   И ВзаиморасчетыСКонтрагентамиПоДокументамРасчетовОстатки.ДокументРасчетовСКонтрагентом.Сделка ССЫЛКА Документ.ЗаказПокупателя
   И ВзаиморасчетыСКонтрагентамиПоДокументамРасчетовОстатки.ДоговорКонтрагента.ВидДоговора = &ВидДоговора
   И ВзаиморасчетыСКонтрагентамиПоДокументамРасчетовОстатки.СуммаВзаиморасчетовОстаток > 0
   И Док_ЗаказПокупателя.Проведен = ИСТИНА
   И РеализацияТоваровУслуг.Проведен = ИСТИНА
   И Док_ЗаказПокупателя.Ответственный.ФизЛицо В(&ССотр)
   И РеализацияТоваровУслуг.Дата МЕЖДУ &ДатаНачала И &ДатаКонца
   И Док_ЗаказПокупателя.Дата МЕЖДУ &ДатаНачала И &ДатаКонца
   И (ЕСТЬNULL(РеализацияТоваровУслуг.ИсточникЗаказа, ЗНАЧЕНИЕ(Перечисление.ИсточникЗаказа.ПустаяСсылка)) = ЗНАЧЕНИЕ(Перечисление.ИсточникЗаказа.ЗаказОтКлиента)
           ИЛИ ЕСТЬNULL(РеализацияТоваровУслуг.ИсточникЗаказа, ЗНАЧЕНИЕ(Перечисление.ИсточникЗаказа.ПустаяСсылка)) = ЗНАЧЕНИЕ(Перечисление.ИсточникЗаказа.ЗаказФаксПочта))

Запрос выполняется ОЧЕНЬ ДОЛГО!!! При этом если убрать из него "Документ.ЗаказПокупателя КАК Док_ЗаказПокупателя" (первые редакции запроса были без него), то отрабатывает все довольно шустренько, но сейчас стоит задача вытащить "Ответственного по заказу". Вытаскивать ответственного просто из "ВзаиморасчетыСКонтрагентамиПоДокументамРасчетовОстатки.ДокументРасчетовСКонтрагентом.Сделка.Ответственный" не позволяет Скул - превышение количества таблиц. В результате пришлось переписать на ЭТО...но что-то ума дать не могу...

ВЫРАЗИТЬ ()

(1) выразить кого?

"ВзаиморасчетыСКонтрагентамиПоДокументамРасчетовОстатки.ДокументРасчетовСКонтрагентом.Сделка.Ответственный" не позволяет Скул - превышение количества таблиц

(2) ну вместо

ГДЕ

  ВзаиморасчетыСКонтрагентамиПоДокументамРасчетовОстатки.ДокументРасчетовСКонтрагентом ССЫЛКА Документ.РеализацияТоваровУслуг
  И ВзаиморасчетыСКонтрагентамиПоДокументамРасчетовОстатки.ДокументРасчетовСКонтрагентом.Сделка ССЫЛКА Документ.ЗаказПокупателя

написать

НЕ (ВЫРАЗИТЬ(ВЫРАЗИТЬ(ВзаиморасчетыСКонтрагентамиПоДокументамРасчетовОстатки.ДокументРасчетовСКонтрагентом КАК Документ.РеализацияТоваровУслуг
).Сделка КАК Документ.ЗаказПокупателя) ЕСТЬ NULL)

вместо
ПО РеализацияТоваровУслуг.Сделка.Ссылка = Док_ЗаказПокупателя.Ссылка

нельзя ли
ПО РеализацияТоваровУслуг.Ссылка = Док_ЗаказПокупателя.Ссылка

(5) И ЧТО ЭТО БУДЕТ??? Как реализация может быть равна заказу?

(6) ну ты и лол

ПО РеализацияТоваровУслуг.Сделка = Док_ЗаказПокупателя.Ссылка

(+5) тфу!!

вместо
ПО РеализацияТоваровУслуг.Сделка.Ссылка = Док_ЗаказПокупателя.Ссылка

нельзя ли
ПО РеализацияТоваровУслуг.Сделка = Док_ЗаказПокупателя.Ссылка

(4) интересная связка, ща попробую

(8) это не принципиально - согласен, что не очень красиво, но на производительность сильно (так сильно) влиять не должно.

(10) принципиально

(10) составные типы следует приводить к определённому значению. это аксиома. Если не требуется работа со всеми типами из составных

(4) чуток быстрее стало, но все-равно медленнее, чем было без "Документ.ЗаказПокупателя"

(12) приводить через "ВЫРАЗИТЬ", как в (4) ?

(14) без Выразить тянет столько таблиц, сколько типов. с выразить - конкретную таблицу. отсюда и ошибка была что слишком много таблиц

(15) ща попробую переделать первоначальный вариант на  "ВЫРАЗИТЬ"

ВЫБРАТЬ
   Док_ЗаказПокупателя.Ответственный КАК МенеджерКС,
   ОстаткиРасчетов.Контрагент КАК Контрагент,
   ОстаткиРасчетов.ДоговорКонтрагента КАК ДоговорКонтрагента,
   РеализацияТоваровУслуг.СуммаДокумента
ИЗ
   РегистрНакопления.ВзаиморасчетыСКонтрагентамиПоДокументамРасчетов.Остатки(
           &ДатаНач,
           ДокументРасчетовСКонтрагентом ССЫЛКА Документ.РеализацияТоваровУслуг
               И ДоговорКонтрагента.ВидДоговора = &ВидДоговора) КАК ОстаткиРасчетов
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
       ПО ОстаткиРасчетов.ДокументРасчетовСКонтрагентом = РеализацияТоваровУслуг.Ссылка
           И (РеализацияТоваровУслуг.Проведен)
           И (РеализацияТоваровУслуг.Дата МЕЖДУ &ДатаНачала И &ДатаКонца)
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.ЗаказПокупателя КАК Док_ЗаказПокупателя
       ПО (РеализацияТоваровУслуг.Сделка = Док_ЗаказПокупателя.Ссылка)
           И (Док_ЗаказПокупателя.Проведен)
           И (Док_ЗаказПокупателя.Ответственный.ФизЛицо В (&ССотр))
           И (Док_ЗаказПокупателя.Дата МЕЖДУ &ДатаНачала И &ДатаКонца)
ГДЕ
   ОстаткиРасчетов.СуммаВзаиморасчетовОстаток > 0

(17) В таком духе

Переделал все на "Выразить" и полностью убрал "Документ.ЗаказПокупателя" и "Документ.РеализацияТоваровУслуг" - теперь отрабатывает все супер :)

Спасибо всем!