Хочу передать ТЗ в СКД, там что-то сделать и обратно получить тоже ТЗ

ПИШУ:

   ТЗ= ТабличнаяЧасть1.Выгрузить();
   
   
   ВнешниеНаборыДанных = Новый Структура;
   ВнешниеНаборыДанных.Вставить("ТЗ",тз);
   
   СхемаКомпоновкиДанных = ЭтотОбъект.ПолучитьМакет("Макет");
   Настройки = СхемаКомпоновкиДанных.НастройкиПоУмолчанию;
   
   КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
   МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных,  Настройки);
         
   ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
   ПроцессорКомпоновки.Инициализировать(МакетКомпоновки, ВнешниеНаборыДанных, ,истина );
   
   ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
   Табл = ПроцессорВывода.Вывести(ПроцессорКомпоновки);

Ругается на этой строке:

Табл = ПроцессорВывода.Вывести(ПроцессорКомпоновки);

"Неизвестный тип макета"

эт что?

эт надо открыть книгу хрусталёвой на стр 480

(2) ну где я ее сейчас найду?

чото типа вот:
ПроцессорВывода.УстановитьОбъект(ТвояТЗ);
ПроцессорВывода.Вывести(ПроцессорКомпоновки);

(4) я так делал:

ТЗ= ТабличнаяЧасть1.Выгрузить();
   
   
   ВнешниеНаборыДанных = Новый Структура;
   ВнешниеНаборыДанных.Вставить("ТЗ",тз);
   
   СхемаКомпоновкиДанных = ЭтотОбъект.ПолучитьМакет("Макет");
   Настройки = СхемаКомпоновкиДанных.НастройкиПоУмолчанию;
   
   КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
   МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных,  Настройки);
         
   ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
   ПроцессорКомпоновки.Инициализировать(МакетКомпоновки, ВнешниеНаборыДанных, ,истина );
   
   Табл=новый таблицаЗначений();
   
   ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
   ПроцессорВывода.УстановитьОбъект(Табл);
   ПроцессорВывода.Вывести(ПроцессорКомпоновки);

(5) и?

(6) тоже самое - ""Неизвестный тип макета""

МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных,  Настройки,,,Тип("
генератормакетакомпоновкиданныхдляколлекциизначений"));

может у ТЗ ситоит типы колонок определить...

При этом если меняю только это:

ТабДок=новый табличныйДокумент;
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;

ПроцессорВывода.УстановитьДокумент(ТабДок);
ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);

т.е. вывожу не в ТЗ, а в Табличный док (больше ничего не меняю) - все работает!

(10) в (8) не шутка, прям дословно пиши

(8) вставил, получил:

{Форма.Форма.Форма(13)}: Ошибка при вызове метода контекста (Выполнить)
   МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных,  Настройки, , ,Тип("генератормакетакомпоновкиданныхдляколлекциизначений"));
по причине:
Ошибка компоновки макета
по причине:
Ошибка генерации макета
по причине:
Не поддерживается вывод таблиц, диаграмм и вложенных отчетов в универсальную коллекцию значений

(12) щас думай, всё по русски

(13) ну не мучай, я уже пару часов на это убил :(

(14) + почему онане поддерживается и как решить?!

(15) да потому что не поддерживается, как ты себе представляеш вывод Диаграммы например в ТЗ? настройка у СКД должна быть такая чтоб в ТЗ имело смысл её ложить

(16)все, понял :)

(16) я до этого выводил в Таблицу...хотя по мне так это логично - результат в виде таблицы выводить в таблицу значений!

Сделал вывод в список значений (в настройках самой СКД) и оно вывелось.

(18) не совем логично, ибо таблицы в СКД - что-то типа вложенного отчета

(19) + и их несколько может быть и т.д.

А почему вотэто надо прописывать, вроде как параметр не обязательный ведь:

МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных,  Настройки,,,Тип("
генератормакетакомпоновкиданныхдляколлекциизначений"));

(21) необязателен, потому что есть значение по умолчанию у него, а оно для вывода в ТП, а не в другие штучки-дрючки

Ок, спасибо!

А можно еще тогда вопрос.
Я кинул на форму элемент ОТБОР и связал его со своим компоновщиком. Получается я могу теперь в отборе добавлять ограничения. А как передать этот отбор ?

(23) зачем передавать? он уже сам на форме, и меняеш ты именно его.
  МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных,  Настройки);
тут они и передаются

(24) сейчас вот так прописал:

ТЗ= ТабличнаяЧасть1.Выгрузить();    
   
   ВнешниеНаборыДанных = Новый Структура;
   ВнешниеНаборыДанных.Вставить("ТЗ",тз);  
   
   СхемаКомпоновкиДанных =ЭтотОбъект.ПолучитьМакет("Макет");
   //Настройки = СхемаКомпоновкиДанных.НастройкиПоУмолчанию;    
   Настройки =  КомпоновщикНастроек.ПолучитьНастройки();
   ДанныеРасшифровки =    Новый ДанныеРасшифровкиКомпоновкиДанных;    
   КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;      
   
   МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных,  КомпоновщикНастроек.ПолучитьНастройки() , ДанныеРасшифровки , ,Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));
   
   ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
   ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки, ВнешниеНаборыДанных, ДанныеРасшифровки );
   
   Табл=новый таблицаЗначений();
         
   ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
   ПроцессорВывода.УстановитьОбъект(Табл);
   ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);  
   
   Для каждого Ст из Табл цикл
       Сообщить(Ст);    
   КонецЦикла;

все, заработало...