Можно ли так: Если ххх(Значение)="Перечисление" Тогда...
что присунуть вместо ХХХ?
ТипЗнч(ЧтоТут)=Тип("ПеречислениеСсылка.СтавкиНДС")не предлагать.
вид перечисления неизвестен и нафиг не нужен.
нужно узнать это справочник или перечисление.

Если Найти(Строка(Тип(Чтото)),"Перечисление")>1 Тогда

>0 то есть

"что присунуть вместо ХХХ"
пятнично, а пятничные ветки закрыли =(

только вот если в наименовании спр будет перечисление= тут думать надо

можно искать "ПеречислениеСсылка"

ПеречисленияМенеджер.ТипВсеСсылки (EnumsManager.AllRefsType)
ПеречисленияМенеджер (EnumsManager)
ТипВсеСсылки (AllRefsType)
Синтаксис:

ТипВсеСсылки()
Возвращаемое значение:

Тип: ОписаниеТипов.

Описание:

Получает описание типов, содержащее типы ссылок перечислений.

Доступность:

Сервер, толстый клиент, внешнее соединение.

Если Значение.Метаданные().Родитель = Метаданные.Перечисления тогда

(7) а если значение простого типа будет?

(1) ругается: Тип не определен

(7) ругается: Поле объекта не обнаружено (родитель)

сижу в отладчике. в Значении сидит - значение перечислдения

(9) отсеки неопределено сразу

ОписаниеТипов.СодержитТип (TypeDescription.ContainsType)
ОписаниеТипов (TypeDescription)
СодержитТип (ContainsType)
Синтаксис:

СодержитТип(<Тип>)
Параметры:

<Тип> (обязательный)

Тип: Тип.
Тип, вхождение которого проверяется.
Возвращаемое значение:

Тип: Булево.
Истина - указанный тип входит в используемые типы; Ложь - в противном случае.
Описание:

Определяет, входит ли указанный тип в используемые данным объектом типы.

Доступность:

Тонкий клиент, веб-клиент, сервер, толстый клиент, внешнее соединение.
Пример:

ПроверяемыйТип = Тип("Строка");
Если ДопустимыеТипы.СодержитТип(ПроверяемыйТип) Тогда
   Сообщить("Описание типов содержит тип " + ПроверяемыйТип);
Иначе
   Сообщить("Описание типов не содержит тип " + ПроверяемыйТип);
КонецЕсли;

Если Метаданные.Перечисления.Содержит(Значение.Метаданные()) тогда

(6) красивше бы это, но теперь немогу понять что в левую часть присунуть .... = Перечисления.ТипВсеСсылки() ? тип и типЗнч всегда лож

Если Перечисления.ТипВсеСсылки().СодержитТип(ТипЗнч(Что определяем)) Тогда
Бинго! это перечисление!!

(14) так работает

(16) ага. тоже гуд
но как все длинно...

(17) ага, "присунь" туда значение строкового типа теперь

(19) все взорвется? вроде строк у меня нет в цикле... наверно...

(20) ну, если тебе (16) длинно, то оставляй (14)

+ (19) в 14 сругалось, 16 выдало Ложь. значит остался один вариант Перечисления.ТипВсеСсылки().СодержитТип(ТипЗнч(Что определяем))

// Функция возвращает имя вида объектов метаданных по типу объекта.
//
// Не обрабатываются точки маршрутов бизнес-процессов.
//
// Параметры:
//  Тип       - Тип прикладного объекта, определенный в конфигурации
//
// Возвращаемое значение:
//  Строка       - имя вида объектов метаданных, например, "Справочник", "Документ" ...
//
Функция ВидОбъектаПоТипу(Тип) Экспорт
   
   Если Справочники.ТипВсеСсылки().СодержитТип(Тип) Тогда
       Возврат "Справочник";
   
   ИначеЕсли Документы.ТипВсеСсылки().СодержитТип(Тип) Тогда
       Возврат "Документ";
   
   ИначеЕсли БизнесПроцессы.ТипВсеСсылки().СодержитТип(Тип) Тогда
       Возврат "БизнесПроцесс";
   
   ИначеЕсли ПланыВидовХарактеристик.ТипВсеСсылки().СодержитТип(Тип) Тогда
       Возврат "ПланВидовХарактеристик";
   
   ИначеЕсли ПланыСчетов.ТипВсеСсылки().СодержитТип(Тип) Тогда
       Возврат "ПланСчетов";
   
   ИначеЕсли ПланыВидовРасчета.ТипВсеСсылки().СодержитТип(Тип) Тогда
       Возврат "ПланВидовРасчета";
   
   ИначеЕсли Задачи.ТипВсеСсылки().СодержитТип(Тип) Тогда
       Возврат "Задача";
   
   ИначеЕсли ПланыОбмена.ТипВсеСсылки().СодержитТип(Тип) Тогда
       Возврат "ПланОбмена";
   
   ИначеЕсли Перечисления.ТипВсеСсылки().СодержитТип(Тип) Тогда
       Возврат "Перечисление";
   
   Иначе
       ВызватьИсключение СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
           НСтр("ru='Неверный тип значения параметра (%1)'"), Строка(Тип));
   
   КонецЕсли;
   
КонецФункции

(23) ага есть такая. но это еще длинше

(24) Это код из святых писаний, т.е. из типовой

// Функция ВидОбъектаПоСсылке возвращает имя вида объектов метаданных
// по ссылке на объект.
//
// Не обрабатываются точки маршрутов бизнес-процессов.
//
// Параметры:
//  Ссылка       - ссылка на объект, - элемент справочника, документ, ...
//
// Возвращаемое значение:
//  Строка       - имя вида объектов метаданных, например, "Справочник", "Документ" ...
//
Функция ВидОбъектаПоСсылке(Ссылка) Экспорт
   
   Возврат ВидОбъектаПоТипу(ТипЗнч(Ссылка));
   
КонецФункции

v8: Получить строку имени Типа из самого типа.

вот бы какой нить справочник святых писаний... бывает много вкусного